Win10下为批处理文件自动添加管理员权限的方法

发布时间:2016-08-09 11:09发布者:系统城-小群浏览数:349

如果windows10系统用户想要在电脑中运行批处理文件的话,一般都需要先手动获取管理员权限才可以。这种“半自动化”设定实际上还是挺麻烦的,要是能够双击运行直接就带管理员权限岂不是更简单?其实这也不难,使用小编提供的代码就可以轻松实现自动获取权限的功能。Win7/Win8.1/Win10各版本均可使用。

推荐:win10系统下载64位

把如下代码(分割线之间)复制到记事本中,并保存为 .bat 格式即可(文件名可自拟):

另存为

————————— 分割线 —————————

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::      软媒魔方自动添加批处理文件管理员权限      ::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

@echo off

CLS

ECHO.

ECHO ================================

ECHO 软媒魔方获取批处理文件管理员权限

ECHO ================================

:init

setlocal DisableDelayedExpansion

set "batchPath=%~0"

for %%k in (%0) do set batchName=%%~nk

set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"

setlocal EnableDelayedExpansion

:checkPrivileges

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges

if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)

ECHO.

ECHO ********************************

ECHO 请求 UAC 权限批准……

ECHO ********************************

ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"

ECHO args = "ELEV " >> "%vbsGetPrivileges%"

ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"

ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"

ECHO Next >> "%vbsGetPrivileges%"

ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"

"%SystemRoot%\System32\WScript.exe" "%vbsGetPrivileges%" %*

exit /B

:gotPrivileges

setlocal & pushd .

cd /d %~dp0

if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::     以下为需要运行的批处理文件代码     ::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem 本行以下可修改为你需要的bat命令(从上面三行冒号开始到下面都可删改)

ECHO 欢迎使用软媒魔方!

ECHO.

pause

————————— 分割线 —————————

以上代码就是为你的bat内容获取管理员权限用的,加在你的代码之前就可以用了。运行效果如下:

运行效果

▲图片说明:如果你的系统开启了UAC,那么就需要运行后批准一下(别嫌麻烦,最好开启UAC,比较安全)

运行示例

▲图片说明:运行示例(有小伙伴嫌CMD丑,所以你可以在属性→颜色中调下背景透明度,再换个喜欢的壁纸……)

属性

这个代码也支持Win7/Win8.1系统,效果如下(Windows7为例):

效果图1

Win7的CMD还没法设置透明背景

▲图片说明:Win7的CMD还没法设置透明背景

复制代码还是比较麻烦,你可以直接下载上述制作好的文件:点此进入网盘

以上就是系统城小编为大家介绍的Win10下为批处理文件自动添加管理员权限的具体方法了。有需要的朋友,只要按照上述步骤操作一遍,相信很快就能成功。

win10系统
最新win7系统下载 | win8 ghost系统下载 | win7旗舰版系统下载
本站发布的系统与软件仅为个人学习测试使用,请在下载后24小时内删除,不得用于任何商业用途,否则后果自负,请支持购买微软正版软件!
如侵犯到您的权益,请及时通知我们,我们会及时处理。
Copyright @ 2011 系统城 版权声明 网站导航